Ticket #9743: jump_ppc64_sysv_elf_gas.S

File jump_ppc64_sysv_elf_gas.S, 10.3 KB (added by Tony Reix <tony.reix@…>, 9 years ago)
Line 
1/*
2 Copyright Oliver Kowalke 2009.
3 Distributed under the Boost Software License, Version 1.0.
4 (See accompanying file LICENSE_1_0.txt or copy at
5 http://www.boost.org/LICENSE_1_0.txt)
6*/
7
8
9/*******************************************************************
10 * *
11 * ------------------------------------------------------------- *
12 * | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | 9 | *
13 * ------------------------------------------------------------- *
14 * | 0 | 4 | 8 | 12 | 16 | 20 | 24 | 28 | 32 | 36 | *
15 * ------------------------------------------------------------- *
16PPC64 Big-Endian:
17 * | R13 | R14 | R15 | R16 | R17 | *
18PPC64 Little-Endian:
19 * | TOC | R14 | R15 | R16 | R17 | *
20 * ------------------------------------------------------------- *
21 * ------------------------------------------------------------- *
22 * | 10 | 11 | 12 | 13 | 14 | 15 | 16 | 17 | 18 | 19 | *
23 * ------------------------------------------------------------- *
24 * | 40 | 44 | 48 | 52 | 56 | 60 | 64 | 68 | 72 | 76 | *
25 * ------------------------------------------------------------- *
26 * | R18 | R19 | R20 | R21 | R22 | *
27 * ------------------------------------------------------------- *
28 * ------------------------------------------------------------- *
29 * | 20 | 21 | 22 | 23 | 24 | 25 | 26 | 27 | 28 | 29 | *
30 * ------------------------------------------------------------- *
31 * | 80 | 84 | 88 | 92 | 96 | 100 | 104 | 108 | 112 | 116 | *
32 * ------------------------------------------------------------- *
33 * | R23 | R24 | R25 | R26 | R27 | *
34 * ------------------------------------------------------------- *
35 * ------------------------------------------------------------- *
36 * | 30 | 31 | 32 | 33 | 34 | 35 | 36 | 37 | 38 | 39 | *
37 * ------------------------------------------------------------- *
38 * | 120 | 124 | 128 | 132 | 136 | 140 | 144 | 148 | 152 | 156 | *
39 * ------------------------------------------------------------- *
40 * | R28 | R29 | R30 | R31 | SP | *
41 * ------------------------------------------------------------- *
42 * ------------------------------------------------------------- *
43 * | 40 | 41 | 42 | 43 | 44 | 45 | | *
44 * ------------------------------------------------------------- *
45 * | 160 | 164 | 168 | 172 | 176 | 180 | | *
46 * ------------------------------------------------------------- *
47 * | CR | LR | PC | | *
48 * ------------------------------------------------------------- *
49 * ------------------------------------------------------------- *
50 * | 46 | 47 | 48 | 49 | | *
51 * ------------------------------------------------------------- *
52 * | 184 | 188 | 192 | 196 | | *
53 * ------------------------------------------------------------- *
54 * | sp | size | | *
55 * ------------------------------------------------------------- *
56 * ------------------------------------------------------------- *
57 * | 50 | 51 | 52 | 53 | 54 | 55 | 56 | 57 | 58 | 59 | *
58 * ------------------------------------------------------------- *
59 * | 200 | 204 | 208 | 212 | 216 | 220 | 224 | 228 | 232 | 236 | *
60 * ------------------------------------------------------------- *
61 * | F14 | F15 | F16 | F17 | F18 | *
62 * ------------------------------------------------------------- *
63 * ------------------------------------------------------------- *
64 * | 60 | 61 | 62 | 63 | 64 | 65 | 66 | 67 | 68 | 69 | *
65 * ------------------------------------------------------------- *
66 * | 240 | 244 | 248 | 252 | 256 | 260 | 264 | 268 | 272 | 276 | *
67 * ------------------------------------------------------------- *
68 * | F19 | F20 | F21 | F22 | F23 | *
69 * ------------------------------------------------------------- *
70 * ------------------------------------------------------------- *
71 * | 70 | 71 | 72 | 73 | 74 | 75 | 76 | 77 | 78 | 79 | *
72 * ------------------------------------------------------------- *
73 * | 280 | 284 | 288 | 292 | 296 | 300 | 304 | 308 | 312 | 316 | *
74 * ------------------------------------------------------------- *
75 * | F24 | F25 | F26 | F27 | F28 | *
76 * ------------------------------------------------------------- *
77 * ------------------------------------------------------------- *
78 * | 80 | 81 | 82 | 83 | 84 | 85 | 86 | 87 | | *
79 * ------------------------------------------------------------- *
80 * | 320 | 324 | 328 | 332 | 336 | 340 | 344 | 348 | | *
81 * ------------------------------------------------------------- *
82 * | F29 | F30 | F31 | fpscr | | *
83 * ------------------------------------------------------------- *
84 * *
85 * *****************************************************************/
86
87#ifdef __LITTLE_ENDIAN__
88.abiversion 2
89#endif
90
91.section ".text"
92.align 2
93.globl jump_fcontext
94
95#ifdef __BIG_ENDIAN__
96.section ".opd","aw"
97.align 3
98#else
99.type jump_fcontext,@function
100.globl jump_fcontext
101#endif
102
103jump_fcontext:
104#ifdef __BIG_ENDIAN__
105.quad .jump_fcontext,.TOC.@tocbase,0
106.previous
107.size jump_fcontext,24
108.type .jump_fcontext,@function
109.globl .jump_fcontext
110.jump_fcontext:
111#else
112 addis %r2, %r12, .TOC.-jump_fcontext@ha
113 addi %r2, %r2, .TOC.-jump_fcontext@l
114 .localentry jump_fcontext,.-jump_fcontext
115#endif
116
117 std %r14, 8(%r3) # save R14
118 std %r15, 16(%r3) # save R15
119 std %r16, 24(%r3) # save R16
120 std %r17, 32(%r3) # save R17
121 std %r18, 40(%r3) # save R18
122 std %r19, 48(%r3) # save R19
123 std %r20, 56(%r3) # save R20
124 std %r21, 64(%r3) # save R21
125 std %r22, 72(%r3) # save R22
126 std %r23, 80(%r3) # save R23
127 std %r24, 88(%r3) # save R24
128 std %r25, 96(%r3) # save R25
129 std %r26, 104(%r3) # save R26
130 std %r27, 112(%r3) # save R27
131 std %r28, 120(%r3) # save R28
132 std %r29, 128(%r3) # save R29
133 std %r30, 136(%r3) # save R30
134 std %r31, 144(%r3) # save R31
135 std %r1, 152(%r3) # save SP
136#ifdef __LITTLE_ENDIAN__
137 std %r2, 0(%r3) # save TOC
138#endif
139
140 mfcr %r0 # load CR
141 std %r0, 160(%r3) # save CR
142 mflr %r0 # load LR
143 std %r0, 168(%r3) # save LR
144 std %r0, 176(%r3) # save LR as PC
145
146 cmpwi cr7, %r6, 0 # test if fpu env should be preserved
147 beq cr7, 1f
148
149 stfd %f14, 200(%r3) # save F14
150 stfd %f15, 208(%r3) # save F15
151 stfd %f16, 216(%r3) # save F16
152 stfd %f17, 224(%r3) # save F17
153 stfd %f18, 232(%r3) # save F18
154 stfd %f19, 240(%r3) # save F19
155 stfd %f20, 248(%r3) # save F20
156 stfd %f21, 256(%r3) # save F21
157 stfd %f22, 264(%r3) # save F22
158 stfd %f23, 272(%r3) # save F23
159 stfd %f24, 280(%r3) # save F24
160 stfd %f25, 288(%r3) # save F25
161 stfd %f26, 296(%r3) # save F26
162 stfd %f27, 304(%r3) # save F27
163 stfd %f28, 312(%r3) # save F28
164 stfd %f29, 320(%r3) # save F29
165 stfd %f30, 328(%r3) # save F30
166 stfd %f31, 336(%r3) # save F31
167 mffs %f0 # load FPSCR
168 stfd %f0, 344(%r3) # save FPSCR
169
170 lfd %f14, 200(%r4) # restore F14
171 lfd %f15, 208(%r4) # restore F15
172 lfd %f16, 216(%r4) # restore F16
173 lfd %f17, 224(%r4) # restore F17
174 lfd %f18, 232(%r4) # restore F18
175 lfd %f19, 240(%r4) # restore F19
176 lfd %f20, 248(%r4) # restore F20
177 lfd %f21, 256(%r4) # restore F21
178 lfd %f22, 264(%r4) # restore F22
179 lfd %f23, 272(%r4) # restore F23
180 lfd %f24, 280(%r4) # restore F24
181 lfd %f25, 288(%r4) # restore F25
182 lfd %f26, 296(%r4) # restore F26
183 lfd %f27, 304(%r4) # restore F27
184 lfd %f28, 312(%r4) # restore F28
185 lfd %f29, 320(%r4) # restore F29
186 lfd %f30, 328(%r4) # restore F30
187 lfd %f31, 336(%r4) # restore F31
188 lfd %f0, 344(%r4) # load FPSCR
189 mtfsf 0xff, %f0 # restore FPSCR
1901:
191
192 ld %r14, 8(%r4) # restore R14
193 ld %r15, 16(%r4) # restore R15
194 ld %r16, 24(%r4) # restore R16
195 ld %r17, 32(%r4) # restore R17
196 ld %r18, 40(%r4) # restore R18
197 ld %r19, 48(%r4) # restore R19
198 ld %r20, 56(%r4) # restore R20
199 ld %r21, 64(%r4) # restore R21
200 ld %r22, 72(%r4) # restore R22
201 ld %r23, 80(%r4) # restore R23
202 ld %r24, 88(%r4) # restore R24
203 ld %r25, 96(%r4) # restore R25
204 ld %r26, 104(%r4) # restore R26
205 ld %r27, 112(%r4) # restore R27
206 ld %r28, 120(%r4) # restore R28
207 ld %r29, 128(%r4) # restore R29
208 ld %r30, 136(%r4) # restore r30
209 ld %r31, 144(%r4) # restore r31
210 ld %r1, 152(%r4) # restore SP
211#ifdef __LITTLE_ENDIAN__
212 ld %r2, 0(%r4) # restore TOC
213#endif
214
215 ld %r0, 160(%r4) # load CR
216 mtcr %r0 # restore CR
217 ld %r0, 168(%r4) # load LR
218 mtlr %r0 # restore LR
219
220 mr %r3, %r5 # use third arg as return value after jump
221 # and as first arg in context function
222
223 ld %r0, 176(%r4) # load PC
224 mtctr %r0 # restore CTR
225
226 bctr # jump to context
227
228#ifdef __BIG_ENDIAN__
229.size .jump_fcontext, .-.jump_fcontext
230#else
231.size jump_fcontext, .-jump_fcontext
232#endif
233
234/* Mark that we don't need executable stack. */
235.section .note.GNU-stack,"",%progbits